%% Cell cycle Qu et al. 2003 Biophysical journal

%% Cyclin
k1                            for _=>CycB.
k2*[CycB]                     for CycB=>_.
k2u*[APC]*[CycB]              for CycB=[APC]=>_.
(k3*[CDK]*[CycB],k4*[CycB-CDK~{p1,p2}]) 
                              for CDK+CycB<=>CycB-CDK~{p1,p2}.
k5*[CycB-CDK~{p1,p2}]         for CycB-CDK~{p1,p2}=>CycB-CDK~{p1}.
k5u*[C25~{p1,p2}]*[CycB-CDK~{p1,p2}]
                              for CycB-CDK~{p1,p2}=[C25~{p1,p2}]=>CycB-CDK~{p1}.
k6*[CycB-CDK~{p1}]            for CycB-CDK~{p1}=>CycB-CDK~{p1,p2}.
[Wee1]*[CycB-CDK~{p1}]        for CycB-CDK~{p1}=[Wee1]=>CycB-CDK~{p1,p2}.
k7*[CycB-CDK~{p1}]            for CycB-CDK~{p1}=>CDK.
k7u*[APC]*[CycB-CDK~{p1}]     for CycB-CDK~{p1}=[APC]=>CDK.

%% Cdc25 
k8                            for _=>C25.
k9*[C25]                      for C25=>_.
k9*[C25~{p1}]                 for C25~{p1}=>_.
k9*[C25~{p1,p2}]              for C25~{p1,p2}=>_.
bz*[C25]                      for C25=>C25~{p1}.
cz*[CycB-CDK~{p1}]*[C25]      for C25=[CycB-CDK~{p1}]=>C25~{p1}.
az*[C25~{p1}]                 for C25~{p1}=>C25.
bz*[C25~{p1}]                 for C25~{p1}=>C25~{p1,p2}.
cz*[CycB-CDK~{p1}]*[C25~{p1}] for C25~{p1}=[CycB-CDK~{p1}]=>C25~{p1,p2}.
az*[C25~{p1,p2}]              for C25~{p1,p2}=>C25~{p1}.

%% Wee1
k10                           for _=>Wee1.
k11*[Wee1]                    for Wee1=>_.
k11*[Wee1~{p1}]               for Wee1~{p1}=>_.
bw*[Wee1]                     for Wee1=>Wee1~{p1}.
cw*[CycB-CDK~{p1}]*[Wee1]     for Wee1=[CycB-CDK~{p1}]=>Wee1~{p1}.
aw*[Wee1~{p1}]                for Wee1~{p1}=>Wee1.

%% APC
(([CycB-CDK~{p1}]^2)/(a^2+([CycB-CDK~{p1}]^2)))/tho
                              for _=[CycB-CDK~{p1}]=>APC.
[APC]/tho                     for APC=>_.

%% CKI
k12                           for _=>CKI.
k13*[CKI]                     for CKI=>_.
(k14*[CKI]*[CycB-CDK~{p1}],k15*[CKI-CycB-CDK~{p1}])     
                              for CKI+CycB-CDK~{p1}<=>CKI-CycB-CDK~{p1}.
bi*[CKI-CycB-CDK~{p1}]        for CKI-CycB-CDK~{p1}=>(CKI-CycB-CDK~{p1})~{p2}.
ci*[CycB-CDK~{p1}]*[CKI-CycB-CDK~{p1}]                  
               for CKI-CycB-CDK~{p1}=[CycB-CDK~{p1}]=>(CKI-CycB-CDK~{p1})~{p2}.
ai*[(CKI-CycB-CDK~{p1})~{p2}] for (CKI-CycB-CDK~{p1})~{p2}=>CKI-CycB-CDK~{p1}.
k16*[(CKI-CycB-CDK~{p1})~{p2}]
                              for (CKI-CycB-CDK~{p1})~{p2}=>CDK.
k16u*[APC]*[(CKI-CycB-CDK~{p1})~{p2}]
                              for (CKI-CycB-CDK~{p1})~{p2}=[APC]=>CDK.

parameter(k1,300).  parameter(k2,5).   parameter(k3,0.15).

% k3=30 in initial model but after addition of CDK as a molecule
% and not a macro, the value has been adapted : 30/200=0.15

parameter(k4,30).   parameter(k5,0.1). parameter(k6,1).
parameter(k7,10).   parameter(k8,100). parameter(k9,1).
parameter(k10,10).  parameter(k11,1).  parameter(k12,0).
parameter(k13,1).   parameter(k14,1).  parameter(k15,1).
parameter(k16,2).   parameter(k2u,50). parameter(k7u,0).
parameter(k16u,25). parameter(c0,200). parameter(a,4).
parameter(tho,25).  parameter(az,10).  parameter(aw,10).
parameter(ai,10).   parameter(bz,0.1). parameter(bw,0.1).
parameter(bi,0.1).  parameter(cz,1).   parameter(cw,1).
parameter(ci,1).    parameter(k5u,1).

% Initial state
present(CDK,200).   present(Wee1,1).   present(CKI,1).
make_absent_not_present.